MetaStock Formulas

HOME   Back to MetaStock Formulas Overview

HACO

Analyzing a candlestick chart gives a quite good idea of what is going on in the market. Candlestick patterns and the resistance or support from price pivots and rising or falling gaps together with the use of trend lines are excellent technical trading tools.

Nevertheless starting a trade and deciding to close a trade, candle after candle, remains a difficult task. HACO or the "Heikin Ashi Candles Oscillator" will help you to decide. The heikin ashi candles technique was introduced by Dan Valcu [2004]. “Using the Heikin-Ashi technique”, Technical Analysis of STOCKS & COMMODITIES, Volume 22: February 2004.

In this formula I am using the heikin ashi average closing price:

haC

haOpen:=(Ref((O+H+L+C)/4,-1) + PREV)/2;
haC:=((O+H+L+C)/4+haOpen+Max(H,haOpen)+Min(L,haOpen))/4;

This is the HACO digital formula:

HACO

avg:=Input("Up TEMA average: ",1,100,34);
avgdn:=Input("Down TEMA Average: ",1,100,34);
haOpen:=(Ref((O+H+L+C)/4,-1) + PREV)/2;
haC:=((O+H+L+C)/4+haOpen+Max(H,haOpen)+Min(L,haOpen))/4;
TMA1:= Tema(haC,avg);
TMA2:= Tema(TMA1,avg);
Diff:= TMA1 - TMA2;
ZlHa:= TMA1 + Diff;
TMA1:= Tema((H+L)/2,avg);
TMA2:= Tema(TMA1,avg);
Diff:= TMA1 - TMA2;
ZlCl:= TMA1 + Diff;
ZlDif:=ZlCl-ZlHa;
keep1:=Alert(haC>=haOpen,2);
keep2:=ZlDif>=0;
keeping:=(keep1 OR keep2);
keepall:=keeping OR (Ref(keeping,-1) AND (C>=O) OR C>=Ref(C,-1));
keep3:=(Abs(C-O)<(H-L)*.35 AND  H>=Ref(L,-1));
utr:=Keepall OR (Ref(keepall,-1) AND keep3);
TMA1:= Tema(haC,avgdn);
TMA2:= Tema(TMA1,avgdn);
Diff:= TMA1 - TMA2;
ZlHa:= TMA1 + Diff;
TMA1:= Tema((H+L)/2,avgdn);
TMA2:= Tema(TMA1,avgdn);
Diff:= TMA1 - TMA2;
ZlCl:= TMA1 + Diff;
ZlDif:=ZlCl-ZlHa;
keep1:=Alert(haC<haOpen,2);
keep2:=ZlDif<0;
keep3:=Abs(C-O)<(H-L)*.35 AND L<=Ref(H,-1);
keeping:=keep1 OR keep2;
keepall:=keeping OR (Ref(keeping,-1) AND (C<O) OR C<Ref(C,-1));
dtr:=If(Keepall OR (Ref(keepall,-1) AND keep3)=1,1,0);
upw:=dtr=0 AND Ref(dtr,-1) AND utr;
dnw:=utr=0 AND Ref(utr,-1) AND dtr;
result:=If(upw,1,If(dnw,0,PREV));
result

Special offer: "Capturing Profit with technical Analysis"

The digital Heikin ashi oscillator super-imposed on the price chart.

Search the Internet

HOME   Back to MetaStock Formulas Overview